Windows11中给文件夹添加备注
2281
起因书接上回 ，以前写的这个版本只适用于Win10，到了win11之后，右键菜单没有了，现在针对Win11的右键菜单进行优化。
效果现在可以在Windows11 新版的右键菜单中添加备注的按钮，无需点击“显示更多选项”。
步骤
1. 备注程序原先采用python进行备注添加，现在更改成用PowerShell 批处理进行添加，运行速度更快。
@echo off
setlocal enabledelayedexpansion
chcp 65001 >nul
set "targetDir=%~1"
if "%targetDir%"=="" (
set /p "targetDir=请拖入文件夹或输入路径: "
)
set "targetDir=%targetDir:"=%"
if not exist "%targetDir%" (
echo.
echo 错误: 路径不存在。
echo.
pause
exit /b
)
pushd "%targetDir%" 2>nul && (popd) || (
echo.
echo 错误: 目标不是一个文件夹。
echo.
pause
exit /b
)
set "iniFile=%targetDir%\desktop.ini"
:input_loop
set "newInfoTip="
echo.
echo 当前目标文件夹: %targetDir%
set /p "newInfoTip=请输入备注内容: "
if "!newInfoTip!"=="" (
echo 备注不能为空，请重新输入。
goto input_loop
)
set "BatTip=!newInfoTip!"
:: 解除文件属性以防止写入被拒绝
if exist "%iniFile%" attrib -r -s -h "%iniFile%"
:: 使用环境变量传递参数，最稳定的方式
powershell -NoProfile -Command ^
"$p = '%iniFile%';" ^
"$t = $env:BatTip;" ^
"try { if (Test-Path $p) { $c = Get-Content $p -Raw -Encoding Unicode; } else { $c = ''; } } catch { $c = ''; }" ^
"if ($c -match '\[\.ShellClassInfo\]') {" ^
" if ($c -match 'InfoTip=.*') { $c = $c -replace 'InfoTip=.*', ('InfoTip=' + $t); }" ^
" else { $c = $c + \"`r`nInfoTip=\" + $t; }" ^
"} else {" ^
" $c = \"[.ShellClassInfo]`r`nInfoTip=\" + $t; " ^
"}" ^
"Set-Content -Path $p -Value $c -Encoding Unicode;"
:: 恢复文件属性
attrib +h +s "%iniFile%"
attrib +r +s "%targetDir%"
echo.
echo ------------------------------------------------
echo 备注添加成功！
echo ------------------------------------------------
echo 文件夹: %targetDir%
echo 备注: !newInfoTip!
echo ------------------------------------------------
echo.
echo 提示:
echo 1. 如果资源管理器当前已打开该文件夹，请按 F5 刷新
echo 2. 如果备注列未显示，请右键点击列标题栏 -^> 更多 -^> 勾选“备注”
echo.
pause
将代码复制，保存为Remark.bat。放到你自己喜欢的地方。 我喜欢将程序装在D盘，于是放在了D:\文件夹备注程序。
2. 添加右键菜单起初也是按照Win10的方法，修改注册表，看看能不能在新版菜单中添加功能。但是win11的右键菜单是单独开发的，无法通过注册表添加。
最终能实现这样的效果，都要多亏这个软件。 Custom Context Menu
这里是使用教程：Windows11自定义右键菜单栏 | Custom Context Menu使用例子
按照教程安装好之后，按照我下面的图片设置参数，将执行文件路径设置为 "D:\文件夹备注程序\Remark.bat"
图标可以自己选择一个好看的ico图片。
匹配文件夹这里只要选择目录
然后点击保存即可。
然后去文件夹，右键就可以看到备注的选项了。